Blitz Basement

CODE LIBRARY >> SMEAR-OUT EFFECTS

Contributed by Sin

This Code allows you to use an image effect in your game.
Thanks to Sin for allowing use of this code on Blitz Basement. You will need a 640x480 image called back.jpg in the same folder as this code.:

; =----------------------------------------------=
;
; S M E A R   E X A M P L E 
; 
; =----------------------------------------------=
;
; Author: Iain Bell
; Email: isb@scms.rgu.ac.uk
; Version: 1.0
; 
; =----------------------------------------------=
;
; Requires timer to be set to control speed.
; Timer in this case is called "GameTimer".
;
; =----------------------------------------------=
; =---------------- CONSTANTS -------------------=
; Set our Screen Size
Global SCREEN_WIDTH = 640
Global SCREEN_HEIGHT = 480
; =------------- DECLARATIONS ------------------=
; Image handlers
Global BackgroundIMG
; Game Timer variables
Global GameTimer, Frames, FrameCount
; =------------- MAIN PROGRAM ------------------=
; Swap out display to graphics mode
Graphics SCREEN_WIDTH,SCREEN_HEIGHT
; Set up our double buffer
SetBuffer BackBuffer()
; Give our application a name
AppTitle "Smear Example"
; Switch mouse pointer off in window mode
HidePointer()
; Set up our game timer
GameTimer = CreateTimer(20)
; Loads graphic for the demo
BackgroundIMG = LoadImage("Back.jpg")
; Start Smear effect
SmeerImage(BackgroundIMG,2)
WaitKey()
; =------------- FUNCTIONS --------------------=
Function SmeerImage(ImageToSmear, Speed)
Local LineCount, YCount, i
; Start at the bottom of the screen
LineCount = SCREEN_HEIGHT
; Repeat for each line of ImageToSmear
Repeat
Frames=WaitTimer(GameTimer)
For FrameCount = 1 To Frames
; Update counter that determines how far up screen we are
LineCount = LineCount - Speed
Next 
; Draw portion of screen that's now non-smeared
DrawBlockRect ImageToSmear, 0,LineCount, 0,LineCount,SCREEN_WIDTH,SCREEN_WIDTH-LineCount
; Calculate how far we start smear effect 
YCount = LineCount
; Repeat until we've reached top of screen
Repeat 
; For each line of Speed
For i = 1 To Speed
; Draw line of original image determined by LineCount
DrawBlockRect ImageToSmear, 0,YCount-i, 0,LineCount,SCREEN_WIDTH,1
Next 
; Calculate next line to do
YCount = YCount - Speed
Until YCount < 0
; Flip screen
Flip
Until LineCount < 0
End Function